Still no success disabling LoadHints...

[legacy-breadbaker]

I want to disable the gameplay hints in the loading screens (the simply don't fit on my neat custom loading screens ).

Tried search on this forum, but all threads about this leave me clueless.

Found some references inside .u files (where the array is put together) but I won't touch those with a 10 foot pole.

I don't want to modify those numerous .int files to blank them out there (also all those mod .int's).
A global switch would be neat!

Any idea?
Or will I have to pray for some feature Epic might put in?

[legacy-aardvarkk]

can you give me an example of the hints you're talking about? (i.e. searchable text)

[legacy-breadbaker]

Originally posted by aardvarkk
can you give me an example of the hints you're talking about? (i.e. searchable text)

The gameplay tips displayed on the loading screen.

in Onslaught.int:
ONSHints=("If you receive a missile lock warning, try to get out of sight quickly!","The Raptor's missiles will automatically lock onto Mantas and other Raptors."
...


There are more in UnrealGame.int:

CTFHints=
DMHints=
TGHints=


UT2K4Assault.int:

ASHints=

and many more (XGame.int, ChaosUT, Jailbreak, ...)

I did a find in files with UltraEdit and searched for Hints in the UT system folder (the WinXP search didn't find any).

[legacy-mkhaos7]

The code that follows was written for me for a mod that i'm working on.
It replaces the loading screen image by one from the screenshots of the map that is going to be played and replace the hints by the description of the map.
To make it work will have to look at you ut2k4.ini (or yourmod.ini) in the [Engine.GameEngine] section and replace the line
ConnectingMenuClass=GUI2K4.UT2K4ServerLoading
for
ConnectingMenuClass=newloading.NewLoadingScreen

So it'll get used. As it requires changes in the ut2004.ini i don't know what consequences it'll have (maybe the server won't let you conect because of the package check), since i didn't tested it connecting to "normal" servers.
But if it work allrigh let me know

class NewLoadingScreen extends UT2K4ServerLoading;

function setText(){
   local int i;
   local array<CacheManager.MapRecord> Maps;

   local string Package, Item, Desc;
   local DecoText DT;

   DrawOpText(Operations[2]).Text = StripMap(MapName);

   class'CacheManager'.static.GetMapList(Maps);
   for (i = 0; i < Maps.Length; i++) {
       if (Maps[i].MapName == MapName) {
            //2k3 Maps aperently don't have their description stored on the Description entry.
            //Code copied from UT2K4Tab_MainSP
			if ( class'CacheManager'.static.Is2003Content(Maps[i].MapName) )
			{
				if ( Maps[i].TextName != "" )
				{
                    if ( !Divide(Maps[i].TextName, ".", Package, Item) )
				    {
						Package = "XMaps";
						Item = Maps[i].TextName;
					}
				}

				DT = class'xUtil'.static.LoadDecoText(Package, Item);
				Desc = class'GUI'.static.JoinArray(DT.Rows, "|");
			}
			else
			    Desc = Maps[i].Description;
          if(Desc == "")
            break; // we found the map but it has no description :(
          else  {
              DrawOpText(Operations[3]).Text = Desc;
              return;
          }
       }
   }

   //Ok, we haven't found the map, show the original thing
   super.SetText();
}

simulated function SetImage()
{
   local int i,j;
   local array<CacheManager.MapRecord> Maps;
   local Material mat;

   class'CacheManager'.static.GetMapList(Maps);
   for (i = 0; i < Maps.Length; i++) {
       if (Maps[i].MapName == MapName) {
          if (Maps[i].ScreenshotRef == ""){ //Map doesn't have screenshot
             break;
          }
          else {
              mat = DLOTexture(Maps[i].ScreenshotRef);
              if( mat.IsA('MaterialSequence')) {
                  //Material sequences are arrays with alternate elements of transicion/ fixed image we only need the fixed ones
                  //This counts are based on the fact that most maps with more than one scren will have
                  //a transiction screen and a real screen alternated. So we alwasy need to get odd entries on the sequence
                  j = Rand(MaterialSequence(mat).SequenceItems.Length /2);
                  mat = MaterialSequence(mat).SequenceItems[2*j + 1].Material;
              }
              DrawOpImage(Operations[0]).Image = mat;
              DrawOpImage(Operations[0]).SetSize(3,2);// Loading screens are 1024x752, textures are 512x256, lets make them match
              return;
          }
       }
   }

   //Ok, we haven't found the map, show the original thing
   super.SetImage();
}

[legacy-breadbaker]

Thanks, thats a first hint. I'm not to fit when it comes to uscript, but I'll work my way through.
Now I know where to start.

[legacy-cknight52]

Just have to say it, love the commadore 64 reference (LOAD "*",8,1)

[legacy-breadbaker]

Originally posted by cknight52
Just have to say it, love the commadore 64 reference (LOAD "*",8,1)

aaah, the good old times.
Can't wait for the Back In Time Live event this september.
That'll be some serious C64 party-music-meet-the-people.