Read config ini file value into Kismet

**ffow** · 06-09-2012, 11:00 PM

Is there a way to read a value from one of the ini files into kismet and if so could someone please point me in the right direction. Most of found is http://udn.epicgames.com/Three/ConfigurationFiles.html but this doesn't indicate whether I can access values from kismet.

**ffow** · 06-11-2012, 04:15 AM

Anybody ... can the config ini files be read from kismet?

**sv13** · 06-11-2012, 05:56 AM

you should probably get value from class which variables are saved to .ini, not directly from ini

**Denara** · 06-11-2012, 06:29 AM

It really depends on which values you want to get into kismet. Custom values are easy to read, since you already have your own class that handles those values. Getting things such as Screen Resolution, or other graphics settings is a bit more complicated.
I did such a thing to implement a dynamic day and night cycle, that saves the current time of day into the UDKGame.ini file when you terminate the game, and loads it again when you start the map. I also made some kismet nodes to directly get the current time, set it to a different value and to save it.

Basically what you would have to do is:
1. Write a class that has access to the values of the .ini file
2. Write your own SeqAct_* Kismet node, that uses your other class to get the value, and pass this value to one of the output-links
3. Use your own Kismet node to access those values in Kismet
4. ??? profit

If you need more help ask here, I can possibly provide you with a simple example for saving and reading a custom value from an INI file.

**100GPing100** · 06-11-2012, 07:02 AM

http://www.youtube.com/watch?v=Sgg8yzk_xHI

I MADE THIS FOR YOU!

**Crusha K. Rool** · 06-11-2012, 07:25 AM

Now if DLLs would be actually included in an UDK installer…

**100GPing100** · 06-11-2012, 07:38 AM

Originally Posted by Crusha K. Rool

Now if DLLs would be actually included in an UDK installer…

You mean that when you compile the game that the dlls aren't included in the installation?

**Denara** · 06-11-2012, 07:51 AM

When you package the game using the Unreal Frontend they are afaik not included. You would have to install the packaged game to a location, put your DLLs inside and repack it using some other tool like Inno Setup

**100GPing100** · 06-11-2012, 08:44 AM

Originally Posted by Denara

When you package the game using the Unreal Frontend they are afaik not included. You would have to install the packaged game to a location, put your DLLs inside and repack it using some other tool like Inno Setup

That sucks o0

**ffow** · 06-11-2012, 08:54 AM

Thanks 100G ... I gather the dll and packaging will cause issues with iOS ?

Denara if you have a simple example to read and save that would be great !

**100GPing100** · 06-11-2012, 09:18 AM

Originally Posted by ffow

Thanks 100G ... I gather the dll and packaging will cause issues with iOS ?

Denara if you have a simple example to read and save that would be great !

You better not use the dll...

Denara's method example:

Code:

class MySavingClass extends Object
     config(MySavingFile);

var config int MyCurrentLevel;
var config string MySavedName;

DefaultProperties
{
}

The 2 variables in that class will be saved to the ini file specified in config.

To read the value:
Next you create the kismet node:

Code:

class SeqAct_GetMyCurrentLevel extends SequenceAction;

var int Value;

event Activated()
{
     local MySavingClass MSC;
     
     MSC = new class'MySavingClass';
     Value = MSC.MyCurrentLevel;
}

DefaultProperties
{
     ObjName = "Get My Current Level";
     ObjCategory = "MyCategory";
     bCallHandler = false;
     
     VariableLinks(0) = (ExpectedType=class'SeqVar_Int',LinkDesc="Value",PropertyName=Value,bWriteable=true);
}

This action node would get the value from the previously created class and pass it onto the linked variable node.
You'd do the same thing for MySavedName but with ExpectedType being class'SeqVar_String'.

To write a value:

Code:

class SeqAct_SetMyCurrentLevel extends SequenceAction;

var int Value;

event Activated()
{
     local MySavingClass MSC;
     
     MSC = new class'MySavingClass';
     MSC.MyCurrentLevel = Value;
     MSC.SaveConfig();
}

DefaultProperties
{
     ObjName = "Set My Current Level";
     ObjCategory = "MyCategory";
     bCallHandler = false;
     
     VariableLinks(0) = (ExpectedType=class'SeqVar_Int',LinkDesc="Value",PropertyName=Value);
}