my Question about modifing Pawn Components...

[Masoud]

Hi;

I add a Component to my pawn. The question is how could I modify dynamically it's Location in UScript in run-time...?

(... I dont want to do this, using "Translation = (X=0.0,Y=0.0,Z=0.0)" in "defaultproperties" ).


Here is my Pawn defaultproperties codes:

defaultproperties
{

Begin Object class=SkeletalMeshComponent name=MyPawn
        ...
End Object
	Mesh = MyPawn
	Components.Add(MyPawn)

      ...


Begin Object class=StaticMeshComponent name=theMesh
	StaticMesh = StaticMesh 'MSDG_Package.Models.myBox';
End Object
	Components.Add(theMesh)
       ...
}

Thanks.

[RattleSN4K3]

Assig the component in your DefaultProperties to a variable. Then...
{ReferenceObject}.SetTranslation(NewTranslation)

In your example: Mesh.SetTranslation(NewTranslation).

[Masoud]

RattleSN4K3:
Thanks for reply:
In DefaultProperties of my Pawn, the Mesh.SetTranslation(NewTranslation) modifies the main mesh of my Pawn, but I want to change the mesh of the component (I mean the second mesh, the attached component )
I don't know how make a reference to this second mesh ( StaticMesh = StaticMesh 'MSDG_Package.Models.myBox'; ), in UnrealScript.

[RattleSN4K3]

By assigning something in the manner of MyMesh=OldMesh, you don't create a clone of a mesh. It's just a reference/pointer to the original object.
Destroying OldMesh will set MyMesh to none when OldMesh gets garbage collected.
If you set something on MyMesh, OldMesh has the same value.
==> It's still the same Object.

So you can assign any, in the defaultproperties, created objects to a variable and use it in the code.

class MyActor1 extends Actor;

// used for reference to the component
var StaticMeshComponent MyComp1;

event PostBeginPlay()
{
	super.PostBeginPlay();

	MyComp1.SetTranslation(vect(10,10,10));
}

defaultproperties
{
	Begin Object class=StaticMeshComponent name=StaticMeshComponent1
		StaticMesh=StaticMesh 'MSDG_Package.Models.myBox'
	End Object
	Components.Add(StaticMeshComponent1)

	// Set the var
	MyComp1=StaticMeshComponent1
}

Another approach

class MyActor1 extends Actor;

event PostBeginPlay()
{
	local StaticMeshComponent TempComp;

	super.PostBeginPlay();

	foreach ComponentList(class'StaticMeshComponent', TempComp) {
		// @TODO check if name is automacally set to NAME_X format
		// temporally compare the prefix name
		if (Left(TempComp.Name, 6) ~= "MyMesh") {
			TempComp.SetTranslation(vect(10,10,10));
		}
	}
}

defaultproperties
{
	Begin Object class=StaticMeshComponent name=StaticMeshComponent1
		StaticMesh=StaticMesh 'MSDG_Package.Models.myBox'
	End Object
	Components.Add(StaticMeshComponent1)
}

Complete dynamically:

class MyActor extends Actor;

var StaticMeshComponent MyComp;

event PostBeginPlay()
{
	local StaticMesh sm;
	
	super.PostBeginPlay();
	
	MyComp = new(self,"MyMesh") class'StaticMeshComponent';
	sm = StaticMesh(DynamicLoadObject("MSDG_Package.Models.myBox", class'StaticMesh'));
	MyComp.SetStaticMesh(sm);
	MyComp.SetTranslation(vect(10,10,10));

	AttachComponent(MyComp);
}

defaultproperties
{
}

Hope, it helps.

[Masoud]

RattleSN4K3:
Thanks, you're awesome..., it works.