GFxUI_PauseMenu issue SOLVED

[Trelec]

Using the toggle method, each time it runs start () to open the pause menu, we reload all components of the flash movie. As a result each button events receive a cumulative effect "OnPressResumeButton ()++". Solved by adding a bool bInitComponents.
Also using the event 'CLIK_press', if we close(false) the pause menu leaving button pressed, the next time you open the pause menu focus will experience problems. Solved switching to 'CLIK_click'.

GFxUI_PauseMenu.uc

/**********************************************************************

Copyright   :   (c) 2006-2007 Scaleform Corp. All Rights Reserved.

Portions of the integration code is from Epic Games as identified by Perforce annotations.
Copyright 2010 Epic Games, Inc. All rights reserved.

Licensees may use this file in accordance with the valid Scaleform
Commercial License Agreement provided with the software.

This file is provided AS IS with NO WARRANTY OF ANY KIND, INCLUDING
THE WARRANTY OF DESIGN, MERCHANTABILITY AND FITNESS FOR ANY PURPOSE.

**********************************************************************/

/**
 * Pause menu implementation.
 * Related Flash content:   ut3_pausemenu.fla
 *
 *
 */
class GFxUI_PauseMenu extends UTGFxTweenableMoviePlayer;

var GFxObject RootMC, PauseMC, OverlayMC, Btn_Resume_Wrapper, Btn_Exit_Wrapper;
var GFxClikWidget Btn_ResumeMC, Btn_ExitMC;

var bool bInitComponents;

// Localized strings to use as button labels
var localized string ResumeString, ExitString;

function bool Start(optional bool StartPaused = false)
{
    super.Start();
    Advance(0);

    if (bInitComponents)
    {
        InitComponents();
    }

    return TRUE;
}

function InitComponents()
{
	RootMC = GetVariableObject("_root");
    PauseMC = RootMC.GetObject("pausemenu");

	Btn_Resume_Wrapper = PauseMC.GetObject("resume");
	Btn_Exit_Wrapper = PauseMC.GetObject("exit");

    Btn_ResumeMC = GFxClikWidget(Btn_Resume_Wrapper.GetObject("btn", class'GFxClikWidget'));
    Btn_ExitMC = GFxClikWidget(Btn_Exit_Wrapper.GetObject("btn", class'GFxClikWidget'));

	Btn_ExitMC.SetString("label", ExitString);
	Btn_ResumeMC.SetString("label", ResumeString);

	Btn_ExitMC.AddEventListener('CLIK_click', OnPressExitButton);
	Btn_ResumeMC.AddEventListener('CLIK_click', OnPressResumeButton);

	AddCaptureKey('XboxTypeS_A');
	AddCaptureKey('XboxTypeS_Start');
	AddCaptureKey('Enter');

    bInitComponents = false;
}

function OnPressResumeButton(GFxClikWidget.EventData ev)
{
    PlayCloseAnimation();
}

function OnPressExitButton(GFxClikWidget.EventData ev)
{
	UTPlayerController(GetPC()).QuitToMainMenu();
}

function PlayOpenAnimation()
{
    PauseMC.GotoAndPlay("open");
}

function PlayCloseAnimation()
{
    PauseMC.GotoAndPlay("close");
}

function OnPlayAnimationComplete()
{
    //
}

function OnCloseAnimationComplete()
{
    UTHUDBase(GetPC().MyHUD).CompletePauseMenuClose();
}

/*
    Launch a console command using the PlayerOwner.
    Will fail if PlayerOwner is undefined.
*/
final function UT_ConsoleCommand(string Cmd, optional bool bWriteToLog)
{
    GetPC().Player.Actor.ConsoleCommand(Cmd, bWriteToLog);
}

defaultproperties
{
    bEnableGammaCorrection=FALSE
	bPauseGameWhileActive=TRUE
	bCaptureInput=true

    bInitComponents=true
}