Bonjour à tous, je viens de créer quelques tutos dont j' ai relayé les liens sur d' autres forums, cela concerne la création de content 3D avec le XSI mod tool en version 7.5 :

Staticmesh:
http://www.youtube.com/watch?v=jKgGh...el_video_title

Skeletalmesh:
http://www.youtube.com/watch?v=6lICN...el_video_title

Animations customs pour le skeletalmesh:
http://www.youtube.com/watch?v=AG5Xr...el_video_title

Désolé pour le son, j' arrive pas à faire mieux.
Pour le script, j' ai quelque peu modifié le code source, ici à chaque fois que l' on tire dessus, on va soit arrêter ou jouer l' animation qu' on a créée.

Voici le code source complet de cet exemple:
Code:
    class Lecube extends Pawn
       HideCategories(AI,Camera,Debug,Pawn,Physics)
       placeable;

    var SkeletalMeshComponent LecubeMesh;         //SkelMeshComp for the turret
    var DynamicLightEnvironmentComponent LightEnvironment;   //For efficient lighting
    var AnimNodeSlot FullBodyAnimSlot;  //Slot node used for playing full body anims
    var bool bActivated;

    simulated event PostInitAnimTree(SkeletalMeshComponent SkelComp)
    {
       super.PostInitAnimTree(SkelComp);
       
       FullBodyAnimSlot = AnimNodeSlot(Mesh.FindAnimNode('FullBodySlot'));     // Works
    }

    event PostBeginPlay()
    {
       Super.PostBeginPlay();
       
       `log("Call to PostBeginPlay", ,'Lecube');  // Debug   
       SetPhysics(PHYS_None);
    }
         
    event TakeDamage(int Damage, Controller EventInstigator, vector HitLocation, vector Momentum, class<DamageType> DamageType, optional TraceHitInfo HitInfo, optional Actor DamageCauser)
    {
       `log("Call to TakeDamage", ,'Lecube');  // Debug
       
       if(FullBodyAnimSlot != None)
       {
          if(!bActivated)
          {
             FullBodyAnimSlot.PlayCustomAnim('LecubeRotating', 1.0, 0.2, 0.2, true, true);
             bActivated = true;
          }
          else
          {
             FullBodyAnimSlot.StopCustomAnim(0.0);
             bActivated = false;
          }
       }
    }

    defaultproperties
    {
       Begin Object Class=DynamicLightEnvironmentComponent Name=MyLightEnvironment
       End Object
       LightEnvironment = MyLightEnvironment
       Components.Add(MyLightEnvironment)
       
       Begin Object class=SkeletalMeshComponent name=SkelMeshComp0
          SkeletalMesh = SkeletalMesh'AD_2254_Content.SkeletalMesh.LecubeSkelMesh'
          AnimTreeTemplate = AnimTree'AD_2254_Content.Anims.LecubeSkelMeshAnimTree'
          PhysicsAsset = PhysicsAsset'AD_2254_Content.SkeletalMesh.LecubeSkelMesh_Physics'
          AnimSets(0) = AnimSet'AD_2254_Content.SkeletalMesh.LecubeSkelMesh_Anims'
          LightEnvironment = MyLightEnvironment
       End Object
       Components.Add(SkelMeshComp0)
       LecubeMesh = SkelMeshComp0
       Mesh = SkelMeshComp0
       
       bEdShouldSnap = true
       bActivated = false
    }
Importation d' une animation pour son personnage utilisant ActorX:
http://www.youtube.com/watch?v=YxVbu...el_video_title