[Tutorial] A basic HUD

[billy7777]

Is it absolutely necessary to put this command line variable in the exe target shortcut?

?game=MyGame


I changed all the config files (DefaultEngine.ini, UTGame.ini, etc.) to start to default with "MyGame.MyGame" - but doesnt seem to be using my version of the game (MyGame)... since I keep seeing the default hud.

[Engine.GameInfo]
DefaultGame=MyGame.MyGame
DefaultServerGame=MyGame.MyGame

Is it alright that my folder is called MyGame and I have a MyGame class
so its MyGame.MyGame?

class MyGame extends UTDeathmatch
config(MyGame);

defaultproperties
{
HUDType=class'MyGame.MyHUD'
}

class MyHUD extends UTHUD;

function DrawGameHud()
{
Canvas.SetPos(Canvas.ClipX/2,Canvas.ClipY/2);
Canvas.SetDrawColor(255,255,255,255);
Canvas.Font = class'Engine'.static.GetMediumFont();
Canvas.DrawTextCentered("Hello World");
}

defaultproperties
{
}

Not sure what I am doing wrong - it seems so very basic - It must be missing some little thing - unless it is absolutely necessary to put the "?game=MyGame" command line in the shortcut - but I dont want to do that!

Since that seems sloppy and wont I have to do that (create new shortcut properties) everytime I package the game?

Thanks

[farshad12]

Is it alright that my folder is called MyGame and I have a MyGame class
so its MyGame.MyGame?

Hi

I dunno if I got your word right. But no, you must have a subfolder called 'classes' within your 'MyGame' folder, and put all of your UC files there, in the 'classes' folder.

[Cozmicaztaway]

Ok, so I just tried this tutorial and then made some stuff of my own and just wanted to say thanks, the bar thing was just what I was looking to do anyway, and now I have a sexy, sexy HUD.

[devilx3]

Hello everyone and thanks to all those who seek to help those most in difficulty, I managed to run the MyHud, unfortunately, although the extends of UTHUD removes some features that I want to integrate these functions are:
1: The written (green bottom left) that communicate who is killed and who enters into the game (I suppose this is the status of goals).
2: The red wheel that indicates which way the shots come when one is struck
3: The message that communicates the central doublekill multikill megakill etc. ..
Thank you for any help

[devilx3]

I solved the problem for those who need it I added this code to MyHud

function DrawGameHud()
{
	local float xl, yl, ypos;
	local float TempResScale;
	local Pawn P;
	local int i, len;
	local UniqueNetId OtherPlayerNetId;

	// Draw any spectator information
	if (UTOwnerPRI != None)
	{
		if (UTOwnerPRI.bOnlySpectator || UTPlayerOwner.IsInState('Spectating'))
		{
			P = Pawn(UTPlayerOwner.ViewTarget);
			if (P != None && P.PlayerReplicationInfo != None && P.PlayerReplicationInfo != UTOwnerPRI)
			{
				if (  UTPlayerOwner.bBehindView )
				{
				DisplayHUDMessage(SpectatorMessage @ "-" @ P.PlayerReplicationInfo.PlayerName, 0.05, 0.15);
			}
			}
			else
			{
				DisplayHUDMessage(SpectatorMessage, 0.05, 0.15);
			}
		}
		else if ( UTOwnerPRI.bIsSpectator )
		{
			if (UTGRI != None && UTGRI.bMatchHasBegun)
			{
				DisplayHUDMessage(PressFireToBegin);
			}
			else
			{
				DisplayHUDMessage(WaitingForMatch);
			}

		}
		else if ( UTPlayerOwner.IsDead() )
		{
		 	DisplayHUDMessage( UTPlayerOwner.bFrozen ? DeadMessage : FireToRespawnMessage );
		}
	}

	// Draw the Warmup if needed
	if (UTGRI != None && UTGRI.bWarmupRound)
	{
		Canvas.Font = GetFontSizeIndex(2);
		Canvas.DrawColor = WhiteColor;
		Canvas.StrLen(WarmupString, XL, YL);
		Canvas.SetPos((Canvas.ClipX - XL) * 0.5, Canvas.ClipY * 0.175);
		Canvas.DrawText(WarmupString);
	}

	if ( bCrosshairOnFriendly )
	{
		// verify that crosshair trace might hit friendly
		bGreenCrosshair = CheckCrosshairOnFriendly();
		bCrosshairOnFriendly = false;
	}
	else
	{
		bGreenCrosshair = false;
	}

	if ( bShowDebugInfo )
	{
		Canvas.Font = GetFontSizeIndex(0);
		Canvas.DrawColor = ConsoleColor;
		Canvas.StrLen("X", XL, YL);
		YPos = 0;
		PlayerOwner.ViewTarget.DisplayDebug(self, YL, YPos);

		if (ShouldDisplayDebug('AI') && (Pawn(PlayerOwner.ViewTarget) != None))
		{
			DrawRoute(Pawn(PlayerOwner.ViewTarget));
		}
		return;
	}

	if (bShowAllAI)
	{
		DrawAIOverlays();
	}

	if ( WorldInfo.Pauser != None )
	{
		Canvas.Font = GetFontSizeIndex(2);
		Canvas.Strlen(class'UTGameViewportClient'.default.LevelActionMessages[1],xl,yl);
		Canvas.SetDrawColor(255,255,255,255);
		Canvas.SetPos(0.5*(Canvas.ClipX - XL), 0.44*Canvas.ClipY);
		Canvas.DrawText(class'UTGameViewportClient'.default.LevelActionMessages[1]);
	}

	DisplayLocalMessages();
	DisplayConsoleMessages();

	Canvas.Font = GetFontSizeIndex(1);

	// Check if any remote players are using VOIP
	if ( (CharPRI == None) && (PlayerOwner.VoiceInterface != None) && (WorldInfo.NetMode != NM_Standalone)
		&& (WorldInfo.GRI != None) )
	{
		len = WorldInfo.GRI.PRIArray.Length;
		for ( i=0; i<len; i++ )
		{
			OtherPlayerNetId = WorldInfo.GRI.PRIArray[i].UniqueID;
			if ( PlayerOwner.VoiceInterface.IsRemotePlayerTalking(OtherPlayerNetId)
				&& (WorldInfo.GRI.PRIArray[i] != PlayerOwner.PlayerReplicationInfo)
				&& (UTPlayerReplicationInfo(WorldInfo.GRI.PRIArray[i]) != None)
				&& (PlayerOwner.GameplayVoiceMuteList.Find('Uid', OtherPlayerNetId.Uid) == INDEX_NONE) )
			{
				ShowPortrait(UTPlayerReplicationInfo(WorldInfo.GRI.PRIArray[i]));
				break;
			}
		}
	}


	// Draw the character portrait
	if ( CharPRI != None  )
	{
		DisplayPortrait(RenderDelta);
	}

	if ( bShowClock && !bIsSplitScreen )
	{
   		DisplayClock();
   	}

	if (bIsSplitScreen && bShowScoring)
	{
		DisplayScoring();
	}

	// If the player isn't dead, draw the living hud
	if ( !UTPlayerOwner.IsDead() )
	{
		DrawLivingHud();
	}

	if ( bHasMap && bShowMap )
	{
		TempResScale = ResolutionScale;
		if (bIsSplitScreen)
		{
			ResolutionScale *=2;
		}
		DisplayMap();
		ResolutionScale = TempResScale;
	}

	DisplayDamage();

	if (UTPlayerOwner.bIsTyping && WorldInfo.NetMode != NM_Standalone)
	{
		DrawMicIcon();
	}

}

[nikolajp]

This doesn't work with the MAY release - Scaleform.
It's like it does not register that you want to use your own UTHUD class.

How to change it, so it does?

[cole.gears]

i have one simple question, this tutorial create a hud from a image created from any software of design, like photoshop???

[Blade[UG]]

This doesn't work with the MAY release - Scaleform.
It's like it does not register that you want to use your own UTHUD class.

How to change it, so it does?

bUseClassicHud=true

[Sleepygamer]

bUseClassicHud=true

Just as an aside, do you get bonus points for repeating the same line over and over? When looking up to do a HUD, I must have seen you say the same thing almost a dozen times in different threads. Kudos to you for keeping your cool about it lol...

[Blade[UG]]

haha.. it's something we've run into a lot, with the new hud stuff, and it apparently isn't obvious, and it's an easy one to answer

[rickjones435]

so I aM new at this and I have followed all the steps. but I am still not seing the new Hud just the olde UTHUD for the June UDK release.

[Dodge]

Hey al, been following the same tutorial, got the hud working fine =]
Managed to tweak it to a bar 8 rectangles long.

The problem I have is, I no longer get on screen messages from my touch triggers, and can no longer interact with the use triggers, does anyone know why this is?

Heres my HUD code:

class GlitchHUD extends UTHUD;



 function DrawBar(String Title, float Value, float MaxValue,int X, int Y, int R, int G, int B)
{

    local int PosX,NbCases,i;

    PosX = X; // Where we should draw the next rectangle
    NbCases = 8 * Value / MaxValue; // Number of active rectangles to draw
    i=0; // Number of rectangles already drawn

    /* Displays active rectangles */
    while(i < NbCases && i < 8)
    {
        Canvas.SetPos(PosX,Y);
        Canvas.SetDrawColor(R,G,B,200);
        Canvas.DrawRect(16,12);

        PosX += 18;
        i++;

    }

    /* Displays deactived rectangles */
    while(i < 8)
    {
        Canvas.SetPos(PosX,Y);
        Canvas.SetDrawColor(255,255,255,80);
        Canvas.DrawRect(16,12);

        PosX += 18;
        i++;

    }

    /* Displays a title */
    Canvas.SetPos(PosX + 4,Y);
    Canvas.SetDrawColor(R,G,B,200);
    Canvas.Font = class'Engine'.static.GetSmallFont();
    Canvas.DrawText(Title);

} 

function DrawGameHud()
{

    if ( !PlayerOwner.IsDead() && !UTPlayerOwner.IsInState('Spectating'))
    {
        DrawBar("LIFE",PlayerOwner.Pawn.Health, PlayerOwner.Pawn.HealthMax,20,20,200,80,80);         
		DrawBar("SHOTGUN AMMO",UTWeapon(PawnOwner.Weapon).AmmoCount, UTWeapon(PawnOwner.Weapon).MaxAmmoCount ,20,40,80,80,200);     }

}


	
	
	function DisplayLocalMessages()
{
	if (!PlayerOwner.bCinematicMode)
	{
		MaxHUDAreaMessageCount = bIsSplitScreen ? 1 : 2;
		Super.DisplayLocalMessages();
	}
}

function DisplayConsoleMessages()
{
	local int Idx, XPos, YPos;
	local float XL, YL;

	if (ConsoleMessages.Length == 0 || PlayerOwner.bCinematicMode)
	{
		return;
	}

	for (Idx = 0; Idx < ConsoleMessages.Length; Idx++)
	{
		if ( ConsoleMessages[Idx].Text == "" || ConsoleMessages[Idx].MessageLife < WorldInfo.TimeSeconds )
		{
			ConsoleMessages.Remove(Idx--,1);
		}
	}
	ConsoleMessagePosX = bDisplayingPowerups ? 0.1 : 0.0;
	XPos = (ConsoleMessagePosX * HudCanvasScale * Canvas.SizeX) + (((1.0 - HudCanvasScale) / 2.0) * Canvas.SizeX);
	YPos = (ConsoleMessagePosY * HudCanvasScale * Canvas.SizeY) + (((1.0 - HudCanvasScale) / 2.0) * Canvas.SizeY);

	Canvas.Font = GetFontSizeIndex(0);

	Canvas.TextSize ("A", XL, YL);

	YPos -= YL * ConsoleMessages.Length; // DP_LowerLeft
	YPos -= YL; // Room for typing prompt

	for (Idx = 0; Idx < ConsoleMessages.Length; Idx++)
	{
		if (ConsoleMessages[Idx].Text == "")
		{
			continue;
		}
		Canvas.StrLen( ConsoleMessages[Idx].Text, XL, YL );
		Canvas.SetPos( XPos, YPos );
		Canvas.DrawColor = ConsoleMessages[Idx].TextColor;
		Canvas.DrawText( ConsoleMessages[Idx].Text, false );
		YPos += YL;
	}
}

defaultproperties
{
MessageOffset(0)=0.15
	MessageOffset(1)=0.242
	MessageOffset(2)=0.36
	MessageOffset(3)=0.58
	MessageOffset(4)=0.78
	MessageOffset(5)=0.83
	MessageOffset(6)=2.0
	
		TextRenderInfo=(bClipText=true)

		
		
}

Thanks

Dodge

[Alexin]

Hey Guys,

I'm getting 2 warnings when trying to run this,

Warning, ClassProperty Engine.GameInfo:HUDType: unresolved reference to 'class'MyFolder.MyHUD

And the other one,

Warning, Invalid property value in defaults: HUDType=class'MyFolder.MyHUD'

Any idea how to fix these things?

Thanks,

[thommie]

i'm thinking you don't have a class named MyHud in the Myfolder\Classes\ folder.

[Alexin]

i'm thinking you don't have a class named MyHud in the Myfolder\Classes\ folder.

I have this,

class MyHUD extends UTHUD;

[thommie]

did you also add the MyFolder to the DefaultEngineUDK.ini file?

[birdhouse13579]

Error, Bad or missing expression after '!': 'UTPlayerOwner'

What am I doing wrong?

E: Fixed it.

[HavocInferno]

The Tut is working nicely for me, also works perfectly with my canvas crosshair... now my question is, the bar is displayed at the top of the screen, I'd like to have it at the bottom...Now just setting the Y (?) value from 20 to, like 740 displays the bar right at the default PIE resolution, but now with other resolution, then it's wrong again. Probably because the Y position is just like a pixel value.

Is there a way to have the bottom placed at the bottom of the screen? Atm it's like "Bar, go down *Value* pixels down from top!", how would you make it "Bar, go up *Value* pixels from bottom!"... like, some -Y somewhere or stuff?