Handling camera rotation with extended GameThirdPersonCameraMode_Default

[roychr]

Ok, with the various options, I was able to get my camera to the right position and let it follow my character with nice interpolation.

The problem I have and it may be related to core third person camera implementation, is that I cannot find a way to put the camera into stock rotation to get a clean RTS Isometric camera. If I try to override the rotations with the pawn calcCamera it will simply ignore basic defaultProperties.

Here is my default camera extention :

class LumeThirdPersonCameraMode_Default extends GameThirdPersonCameraMode_Default;

var float FOV;

function float GetDesiredFOV( Pawn ViewedPawn )
{
	return FOV;
}

DefaultProperties
{
	FOV=90.f;
	PawnRelativeOffset=(x=0,y=192,z=192)
	bLockedToViewTarget=FALSE
	bFollowTarget=TRUE
	bInterpLocation=TRUE
	bInterpRotation=TRUE
	bSkipCameraCollision=TRUE
	BlendTime=0.75
}

Now just like PawnRelativeOffset, is there a relativeRotation ?

[itach1]

I know that there probably is because you can set your relative rotation I believe if you do all this in Kismet.

[roychr]

I am getting really tired of trying to put a simple overhead camera in UDK, might default to Kismet now, in Unity, it took 15 min. to code in javascript with Z axis zoom in/out and panning when cursor went near corners. Please if somebody has an answer I am really out of options, and since all the axises are messed up it does'nt really help me to get it right.

I got a question, if I use kismet for initializing the camera and I stream the levels of my game, do I have to copy paste the OnLevelLoaded kismet code in all my level ?

[ddelion]

You don't need to use GameThirdPersonCamera class from GameFramework. Instead you need to implement your own camera, maybe extend it from GameBaseCamera. And then in yours PlayerCamera class in function FindBestCameraType you need to return your type of camera. Epics code don't have 'out of the box' RTS camera.

[roychr]

Well thats what I feared I would have to do. The big problem with that is that we have absolutely no documentation except the code which is a bit hardcore to understand sometimes, especially when there is CPP declaration and we just have no clue as to what the functions does. Does someone knows about a tutorial that exist on the internet that I could use as a starting point ?

[Chris2009]

You don't need to use GameThirdPersonCamera class from GameFramework. Instead you need to implement your own camera, maybe extend it from GameBaseCamera. And then in yours PlayerCamera class in function FindBestCameraType you need to return your type of camera. Epics code don't have 'out of the box' RTS camera.

Why would you do that? The ThirdPersonCamera already provided is excellent.

All you have to do is overide the correct functions and you can make the camera do what ever you want.

[roychr]

Why would you do that? The ThirdPersonCamera already provided is excellent.

All you have to do is overide the correct functions and you can make the camera do what ever you want.

Do you know how to change the rotations with the defaultproperties then ?

[Viion]

I really hope you figure this out as im looking for a similar approach and pretty much stuck in same boat as you.

[Chris2009]

Override this function in your playerController

class function UpdateRotation( float DeltaTime )

Do rotation adjustment.......

set your cam to thirdperson

[roychr]

Override this function in your playerController

class function UpdateRotation( float DeltaTime )

Do rotation adjustment.......

set your cam to thirdperson

ok here's the deal, it works, i simply copied the PlayerController UpdateRotation and added a few things as well as remove the delta for player inputs as I do not want the player to change the rotation at all :

function UpdateRotation( float DeltaTime )
{
	local Rotator	DeltaRot, newRotation, ViewRotation;

	ViewRotation = Rotation;
	if (Pawn!=none)
	{
		Pawn.SetDesiredRotation(ViewRotation);
	}

	//BEING EDIT-----
	// Calculate Delta to be applied on ViewRotation
	//DeltaRot.Yaw	= PlayerInput.aTurn;
	//DeltaRot.Pitch	= PlayerInput.aLookUp;

	
	ViewRotation.Pitch = (-55.0f * DegToRad) * RadToUnrRot;
	ViewRotation.Yaw = (-45.0f * DegToRad) * RadToUnrRot;
	//END EDIT-----
	ProcessViewRotation( DeltaTime, ViewRotation, DeltaRot );
	SetRotation(ViewRotation);

	ViewShake( deltaTime );

	NewRotation = ViewRotation;
	NewRotation.Roll = Rotation.Roll;

	if ( Pawn != None )
		Pawn.FaceRotation(NewRotation, deltatime);
}

The problem I am now facing is that the camera keeps bobbing up and down. Also I noticed drawing artifacts that maybe related to parralax shader ??

Here is the video :

http://www.youtube.com/watch?v=EsB_6PoIjIk

Any Idea what could cause that ?

[Chris2009]

	ViewRotation.Pitch = (-55.0f * DegToRad) * RadToUnrRot;
	ViewRotation.Yaw = (-45.0f * DegToRad) * RadToUnrRot;

This is the problem I think.

Unreal uses Unreal units or UU for short.

65535 uu = 360 degrees.

so if you want the rotation to be fixed just set the pitch and yaw to a number within this range.

example would be if you put the pitch to -16000 then the rotation would be directly above, facing down.

hope this helps

edit: Also i dont think you need to used this

NewRotation = ViewRotation;
NewRotation.Roll = Rotation.Roll;

try removing it.

Look at my example

http://www.moddb.com/members/plus1/v...udk-movement-3

[roychr]

Does your Game extends UTDeathmatch &&
Controller extends UTPlayerController &&
Pawn extends UTPawn ?

[roychr]

I just clicked on the bobbing issue, its the effect of the player walking. Though I do not know if it is supposed to be there in third person...

[roychr]

Ok I GOT IT WORKING !!!!!!!

I will write of a tutorial for it on my blog, it is definitly a first step in the right direction, next will be mouse inputs with raycasting on the floor. Its sad that you got it working and not me, but at the very least I know its doable, not that I had any doubts....

[Chris2009]

So how did you get it working?

[rahatropa]

Glad to hear you got it working!

Chris I'd just like to say I'm very impressed with your video demo! Your progress (in your short UScript experience) is what inspires me most to keep chuggin away at Unrealscript. I'm fairly sure that my constant headaches and lack-of-progress with UScript is because I can't get my head around how all the different components of UE, such as the HUD, UI, etc. all relate to one another.

Question- you've managed to get a mouse controller working, something I'm trying to achieve as well, other than creating a new UIScene/HUD (my understanding is these are the same with the exception of a few variable settings) did you also have to mess with any input configs/settings? I've programmed raycasting playercontrollers in other engines, but UE is proving to be rather difficult.. Cliffs on my question: What components will be required of a mouse-controller.. a custom playercontroller, custom hud(or UI? my understanding is these are the same with the exception of a few variables differentiating the two), will I also need a custom game and something related to input?

I already have a 3rd person static camera that follows my player. Any tutorials, tips, or comments would be appreciated!

[roychr]

this is my default properties for my third person cam

class xxxThirdPersonCameraMode_Default extends GameThirdPersonCameraMode_Default;

var float FOV;

function float GetDesiredFOV( Pawn ViewedPawn )
{
	return FOV;
}

DefaultProperties
{
	FOV=90.f;
	TargetRelativeCameraOriginOffset=(x=-192,y=192,z=192)
	bLockedToViewTarget=TRUE
	bFollowTarget=FALSE
	bInterpLocation=TRUE
	bInterpRotation=TRUE
	bSkipCameraCollision=TRUE
	BlendTime=0.75
}

and my main class extends GameInfo with :

defaultproperties
{
	bDelayedStart=false
	PlayerControllerClass=class'xxx.xxxPlayerController'
	DefaultPawnClass=class'xxx.MyPawn'

	Name="Default__xxxGameInfo"
}

My pawn declaration is a mix of a class taken somewhere else :

class MyPawn extends GamePawn
	config(Game);

simulated function name GetDefaultCameraMode( PlayerController RequestedBy )
{
	`Log("xxx: Requested Third person camera Mode");
    return 'ThirdPerson';
}

defaultproperties
{
	Components.Remove(Sprite)

	Begin Object Class=DynamicLightEnvironmentComponent Name=MyLightEnvironment
		ModShadowFadeoutTime=0.25
		MinTimeBetweenFullUpdates=0.2
		AmbientGlow=(R=.01,G=.01,B=.01,A=1)
		AmbientShadowColor=(R=0.15,G=0.15,B=0.15)
		LightShadowMode=LightShadow_ModulateBetter
		ShadowFilterQuality=SFQ_High
		bSynthesizeSHLight=TRUE
	End Object
	Components.Add(MyLightEnvironment)

    Begin Object Class=SkeletalMeshComponent Name=InitialSkeletalMesh
		CastShadow=true
		bCastDynamicShadow=true
		bOwnerNoSee=false
		LightEnvironment=MyLightEnvironment;
        BlockRigidBody=true;
        CollideActors=true;
        BlockZeroExtent=true;
		PhysicsAsset=PhysicsAsset'CH_AnimCorrupt.Mesh.SK_CH_Corrupt_Male_Physics'
		AnimSets(0)=AnimSet'CH_AnimHuman.Anims.K_AnimHuman_AimOffset'
		AnimSets(1)=AnimSet'CH_AnimHuman.Anims.K_AnimHuman_BaseMale'
		AnimTreeTemplate=AnimTree'CH_AnimHuman_Tree.AT_CH_Human'
		SkeletalMesh=SkeletalMesh'CH_LIAM_Cathode.Mesh.SK_CH_LIAM_Cathode'
	End Object

	Mesh=InitialSkeletalMesh;
	Components.Add(InitialSkeletalMesh);
}

I got a basic extended camera :

class xxxPlayerCamera extends GamePlayerCamera;

protected function GameCameraBase FindBestCameraType(Actor CameraTarget)
{
	return ThirdPersonCam;
}

defaultproperties
{
	ThirdPersonCameraClass=class'xxx.xxxThirdPersonCamera'
}

With the declaration for third person :

class xxxThirdPersonCamera extends GameThirdPersonCamera;

DefaultProperties
{
	ThirdPersonCamDefaultClass=class'xxx.xxxThirdPersonCameraMode_Default'
}

And at last the playerController :

class xxxPlayerController extends PlayerController
	config(Game);


function UpdateRotation( float DeltaTime )
{
	local Rotator	ViewRotation;

	ViewRotation.Pitch = (-45.0f * DegToRad) * RadToUnrRot;
	ViewRotation.Yaw = (-45.0f * DegToRad) * RadToUnrRot;

	SetRotation(ViewRotation);
}


defaultproperties
{
	CameraClass=class'xxx.xxxPlayerCamera'
}

I will at some point check the values of the DegToRad and stuff and put a static value, so its a bit more optimized, but for the moment i like human readable stuff.

So it was only to basically do a SetRotation.

As rahatropa states, the mouse and point and click would help alot of people that are not interested in FPS's, I could take that time and try to get decent path finding in my game instead of doing this. In Unity it was quite simple, but in UDK once you know how, it is equivalent time-wise, but the learning curve is higher a bit.

[Chris2009]

Yes I see now, I have been looking at too much code, suprised I didn't see that.

The next thing I've managed to do is a Material projection at my cursor location when I click the ground.

Only a coulple of lines of code.


To do the mouse point and click you need to do a few things. I think I will write a tutorial on this because a lot of people are asking daily.


You need to grab the mouse cursor location and project from screen space to world space. Hint: (Look in UIRoot for the mouse)

ScreenToWorld: you can either use Deproject. Which I havn't had got working yet.

Or write your own function. (Which is what I did.)

As for path finding, I was find that calcualting the distance between to vectors was not to accurate, must be the way I implemented it, but I soon solved this, that was the hardest thing.

then trace the loaction.

[LordsWarrior]

To do the mouse point and click you need to do a few things. I think I will write a tutorial on this because a lot of people are asking daily.

That would be so much appreciated man.
Im trying similar and been searching "Mouse" / "Cursor" etc. There is lots of bits of information, but struggling to find the full picture.

Cheers

-LW

[roychr]

As I can see, GetCursorPosition( X, Y) is callable statically with the following syntax :

local int x,y;
class'UIRoot'.static.GetCursorPosition( X, Y );

you can check inside UTScoreboardPanel.uc. (function Vector GetMousePosition)

Again it will be a kind of witch hunt to get the pieces together like LordsWarrior was saying. Chris I will be very interested in decal projection if you have other cues about it I will gladly take any direction.

And thanks for the rotation thing, it has helped me alot to navigate into the code and understand some camera concepts.

[roychr]

To get Camera mouse for example debug output, do the following inside your PlayerController class :

event PlayerTick( float DeltaTime )
{
	local int x,y;

	super.PlayerTick(DeltaTime);

	class'UIRoot'.static.GetCursorPosition( x, y );
	`Log("Mouse pos X" @ x @ "Mouse pos Y" @ y);
}

Like explained on line 3038 of PlayerController.uc, "Every tick, the PlayerTick() function is called." I will check if I can rapidly get mouse cursor in action, but I guess its a bit more code...

[RJM74]

** Nevermind.

[Teto]

I tried your code once.
It worked, one time, but I wasn't satisfied because when the camera hit a wall, it goes inside.
So I Tried few things that didn't work. After that I was unable to have the isometric view again.
I knew that UDK is mainly an FPS tool, but at this point... Since you want using something else that the DeatMatchXXX classes can do, you have problems... For example, today, I had 2 weapons on screen, one for firstPerson view, and the other one for 3rd, but without body!

[roychr]

put the default properties bSkipCameraCollision=TRUE to FALSE then you will be able to enable collision and best placement for camera. But you should know that its one thing to have an Iso cam, but you should always make your levels accordingly to the camera so its not obstructed by level meshes. There are some compromise that are required for these types of games, this is one.

[RJM74]

Thankyou for sharing this roychr, it has been very helpfull.

I have made a few adjustments to it but nothing really major coding wise, just inserted a few other commands into your thirdpersoncameramode_default and adjusted your playercamera script.

** I removed the adjustments I made as I realised I had made them after I had done a few changes to your scripts and not entirely sure how it would effect your scripts views.

[50p]

* Forget it *

[Bailar]

To: Chris2009

Chris I've found Your Videos

Can you upload source code of you scripts or tell How did you force camera to moves independently from the character?
The second question is - how to make zoom in/out with mouse wheel?
And the third - how make character to face to the direction where it runs? Now it's move only forward but in other direction
it moves like strafe or backward running.

[RJM74]

I wanted to achieve something similar as you Bailer so far this is what modifications I have made to roychr's scripts to get the character to face the direction you are heading.

In the xxxPlayerController class I have changed the update rotation function to this..

function UpdateRotation( float DeltaTime )
{
local Rotator DeltaRot, ViewRotation;

ViewRotation = Rotation;

DeltaRot.Yaw = PlayerInput.aTurn;

ProcessViewRotation( DeltaTime, ViewRotation, DeltaRot );

SetRotation(ViewRotation);

Pawn.FaceRotation(ViewRotation, DeltaTime);
}


The xxxThirdPersonCameraMode_Default only has a slight adjustment to the defaultproperties settings but is more of personal view taste than actualy being a requirement.

defaultproperties
{
FOV=120.f;
PawnRelativeOffset=(x=-120,y=0,z=120)
BlendTime=0.75
}

The PawnRelativeOffset x,y,z defines how far away and position the camera is from the pawn.

[Reclusiarch]

This is exactly where I want to go with the UDK. However I decided to skip your Isometric fixed Camera, I also made > SetBehindView(false); in PlayerController so I have a kind of Oblivion/Morrowind action going on with a independent mouse cursor/picker. However my look camera view still follows the mouse.

I was wondering if you knew how to make it so that camera will follow only during the right mouse button held. Once the right mouse button is released camera is fixed.

[dr3k]

why when i set a weapon for the player, i can shoot, but i cant see the weapon on the pawn hands?

[roychr]

probably because its not attached as a component in the pawn default properties. But i am not 100% sure

[Gateway]

I'm in the process of working on something similar but keeping a sort of side scroller camera similar to what they did in shadow complex, how ever looking over some of your code im wondering if it could be modified a bit to work on side scrolling?

[roychr]

I kind decided to go with full extention of the camera class after having some problems with that, but I thing you could do it.

[Mastershadow]

Roychr, I'm using your camera code (thanks!) and I was wondering if you knew why the pawns show up invisible. I'm not really worried about the players character since hes hidden under the world but the baddies need to show up!

This is what should happen...
http://www.livestream.com/mastershad...3-bb41de276422

This is what happens when I run the game with the camera script.
http://www.livestream.com/mastershad...8-4eea2e8e222c

[roychr]

MasterShadow, I suggest you use the script from the website and not this modification to the 3rd person cam, it is intended as a starting point to understand camera's. It is indeed weird that the other pawns are simply not drawned to screen. So try the iso camera on my website, it is better designed for this kind of view.

[Mastershadow]

The only tutorial I can get working on the April UDK release is this one: http://x9productions.com/blog/?p=250

I have downloaded the source code for chapter 1, chapter 2 and even the last chapter6/7 w/ map file and none of them work. I get a yellow warning message in the console about the 4 lines you have us change in the .ini files and the camera is stuck in first person/fly mode.

It also in the console window says that it fails to load class MyIsometricGame.IsometricGameInfo and then fails to find the MyIsometricGame.IsometricGameInfo object twice.

All three versions I tried downloading the source code for also constantly tell me my scripts are out of date and ask me to build every time I start the debugger no matter how often I build the project.

I would love to be able to make your code work so I can tear it a part through trial and error (especially the cursor part...) but I can't seem to get it working. Maybe I should try installing the Feb version? Only problem w/ that is there are supposed to be 3 other ppl working on this w/ me from school.

[roychr]

I have the march version, i did not receive the april notification, i will try to check it out, but your the first to report this problem, maybe people did not took the time to tell me. I will look this out this week end and upgrade the project files.

You should be able in all situation to fix the warnings or errors yourself.

[Mastershadow]

I wish I was at that point where I could fix these things myself. I keep toying around in the code but usually end up breaking it beyond repair and starting over. ; ;

[jeust]

hello ...
it wants to know?
this way of the screen to go alone for right ?
this mode ?



sorry my english..