How do I edir the loadscreen text?

[legacy-Mohlraax]

Is there an easy way to edit the tooltips, or remove them, and is there a way to edit the loadtext position?!

Thanks for the help!

[legacy-Homicidal]

belive the lines are in the ut2004.ini, not sure tho

[legacy-Mohlraax]

Hm... not realy... I cant find it at least...!

[legacy-breadbaker]

They are in various .int files, e.g. Onslaugt.int, UT2k4Assault.int, UnrealGame.int ...

Try a 'find in files' and search for Hints= in *.int files.

[legacy-Mohlraax]

Aha! I found the hints... but the ting was, I wanted to REMOVE the hints from the loading... and maybe center the maploading text... just to customize the loading screen thing a little more... is this even posible?!

[legacy-neoflame]

Originally posted by Mohlraax
Aha! I found the hints... but the ting was, I wanted to REMOVE the hints from the loading... and maybe center the maploading text... just to customize the loading screen thing a little more... is this even posible?!

Center, I don't think so. Delete, just replacing the stuff in brackets with '("")' would probably work.

[legacy-Mohlraax]

Originally posted by neoflame
Center, I don't think so. Delete, just replacing the stuff in brackets with '("")' would probably work.

BAH! Thats not enought... I want to remove all the text, unless the map name, and center that at the bottom! Like UT99, just with the mapname instead of "loading..."!

[legacy-neoflame]

Originally posted by Mohlraax
BAH! Thats not enought... I want to remove all the text, unless the map name, and center that at the bottom! Like UT99, just with the mapname instead of "loading..."!

I'm fairly sure you can't do that, either without coding, or possibly just not at all.

[legacy-Mohlraax]

They did so in alien swarm! There is a way... thats for sure!

[legacy-Mohlraax]

:cry: I waaant toooo!

*bump*

[legacy-neoflame]

Originally posted by Mohlraax
:cry: I waaant toooo!

*bump*

The Alien Swarm people wrote their own code. If you wrote your own GUI class or something maybe :noob:

Actually, if you're willing to wait a bit and rely on my goodwill I might do it for you

Do you want just the mapname or the mapname and 'Loading'?

[legacy-Mohlraax]

How hard can it be to code that little piece?
I whould realy like your help tho! ... but I whould like to see HOW anyways... couse I want to learn from it!

I'll look more into it tomorrow... tell me if you find anything! Its 4:07AM... better get some rest on the eyes... later...!

[legacy-neoflame]

You'd be surprised how hard some easy things can be.

But here, you're in luck, as long as you know how to compile things; it's really easy.

Unfortunately, I don't know if it'll work online

See ya

[legacy-breadbaker]

I've wanted to remove loading hints, too.
Tried to dig into this but didn't had time to go any deeper on this issue.

Maybe the following snippet will help you removing the loading hints:

Originally posted by mkhaos7
The code that follows was written for me for a mod that i'm working on.
It replaces the loading screen image by one from the screenshots of the map that is going to be played and replace the hints by the description of the map.
To make it work will have to look at you ut2k4.ini (or yourmod.ini) in the [Engine.GameEngine] section and replace the line
ConnectingMenuClass=GUI2K4.UT2K4ServerLoading
for
ConnectingMenuClass=newloading.NewLoadingScreen

So it'll get used. As it requires changes in the ut2004.ini i don't know what consequences it'll have (maybe the server won't let you conect because of the package check), since i didn't tested it connecting to "normal" servers.
But if it work allrigh let me know

class NewLoadingScreen extends UT2K4ServerLoading;

function setText(){
   local int i;
   local array<CacheManager.MapRecord> Maps;

   local string Package, Item, Desc;
   local DecoText DT;

   DrawOpText(Operations[2]).Text = StripMap(MapName);

   class'CacheManager'.static.GetMapList(Maps);
   for (i = 0; i < Maps.Length; i++) {
       if (Maps[i].MapName == MapName) {
            //2k3 Maps aperently don't have their description stored on the Description entry.
            //Code copied from UT2K4Tab_MainSP
			if ( class'CacheManager'.static.Is2003Content(Maps[i].MapName) )
			{
				if ( Maps[i].TextName != "" )
				{
                    if ( !Divide(Maps[i].TextName, ".", Package, Item) )
				    {
						Package = "XMaps";
						Item = Maps[i].TextName;
					}
				}

				DT = class'xUtil'.static.LoadDecoText(Package, Item);
				Desc = class'GUI'.static.JoinArray(DT.Rows, "|");
			}
			else
			    Desc = Maps[i].Description;
          if(Desc == "")
            break; // we found the map but it has no description :(
          else  {
              DrawOpText(Operations[3]).Text = Desc;
              return;
          }
       }
   }

   //Ok, we haven't found the map, show the original thing
   super.SetText();
}

simulated function SetImage()
{
   local int i,j;
   local array<CacheManager.MapRecord> Maps;
   local Material mat;

   class'CacheManager'.static.GetMapList(Maps);
   for (i = 0; i < Maps.Length; i++) {
       if (Maps[i].MapName == MapName) {
          if (Maps[i].ScreenshotRef == ""){ //Map doesn't have screenshot
             break;
          }
          else {
              mat = DLOTexture(Maps[i].ScreenshotRef);
              if( mat.IsA('MaterialSequence')) {
                  //Material sequences are arrays with alternate elements of transicion/ fixed image we only need the fixed ones
                  //This counts are based on the fact that most maps with more than one scren will have
                  //a transiction screen and a real screen alternated. So we alwasy need to get odd entries on the sequence
                  j = Rand(MaterialSequence(mat).SequenceItems.Length /2);
                  mat = MaterialSequence(mat).SequenceItems[2*j + 1].Material;
              }
              DrawOpImage(Operations[0]).Image = mat;
              DrawOpImage(Operations[0]).SetSize(3,2);// Loading screens are 1024x752, textures are 512x256, lets make them match
              return;
          }
       }
   }

   //Ok, we haven't found the map, show the original thing
   super.SetImage();
}

[legacy-Mohlraax]

Hm... the job just got intresting! If you just learn wtf that means, I bet it will be a piece of cake! I take the chalange!

... I smell antitcc problems tho... but its worth a try!

[legacy-breadbaker]

Originally posted by Mohlraax
...
... I smell antitcc problems tho... but its worth a try!

Was my first guess, too.

but since you just point your ini to the new loader class it should just work like the custom main menus.

[legacy-neoflame]

Time to clear some stuff up

If you just want to remove the hints, the following will suffice:

class NoHintServerLoading extends UT2K4ServerLoading;

defaultproperties
{
    Operations(3)=None
}

Then in your UT2004.ini, change

ConnectingMenuClass=GUI2K4.UT2K4ServerLoading

to

ConnectingMenuClass=YourPackageNameHere.NoHintServerLoading

If you want to move the other text around, on the other hand, you have to add more stuff into defaultproperties. This is what I threw together yesterday night:

// MohlraaxServerLoading - Mohlraax's Custom Server Loading Screen
// Coded by Neoflame, 20 July 2004, as requested by Mohlraax
// Loading screen with only the mapname

class MohlraaxServerLoading extends UT2K4ServerLoading;

defaultproperties
{
    Begin Object Class=DrawOpImage Name=OpBackground
        Top=0
        Lft=0
        Width=1.0
        Height=1.0
        DrawColor=(R=255,B=255,G=255,A=255)
        SubXL=1024
        SubYL=768
    End Object
    Operations(0)=OpBackground

    Begin Object Class=DrawOpText Name=OpLoading
        Top=0.475
        Lft=0.0
        Height=0.05
        Width=1.0
        Justification=1
        Text="LOADING"
        FontName="XInterface.UT2LargeFont"
        bWrapText=False
    End Object
    Operations(1)=OpLoading

    Begin Object Class=DrawOpText Name=OpMapname
        Top=0.9
        Lft=0.0
        Height=0.035
        Width=1.0
        Justification=1
        FontName="XInterface.UT2LargeFont"
        bWrapText=False
    End Object
    Operations(2)=OpMapname
    
    Operations(3)=None
}

In no case do you have to modify the functions.

[legacy-fiLa]

Originally posted by breadbaker
I've wanted to remove loading hints, too.
Tried to dig into this but didn't had time to go any deeper on this issue.

Maybe the following snippet will help you removing the loading hints:

FINALY someone is working on such a mod!! :up: :up:

[legacy-neoflame]

Come on, no response to my overly long post?

Mohlraax, here's a loadscreen with the LOADED text centered, the mapname in the bottom centered, and the hints removed:

http://dl.downloadhosting.com/downlo...verLoading.zip

[legacy-Mohlraax]

OMG neoflame! Thats freyking sweet!

Now we're talking... thats even a little understandable for a guy like me!
Ok, let me play around a little with this, and we'll see what comes out of it!
btw, is Justification=1 to center the text?! ... and, where exactly do I write these scripts? In ued I guess, but I cant find that script editor! :noob:

[musilowski]

This is a bit OT, but is it possible to change the messages on the screen (in example; "Head Shot!") without affecting AntiTCC and stuff?

[legacy-neoflame]

Originally posted by Mohlraax
OMG neoflame! Thats freyking sweet!

Now we're talking... thats even a little understandable for a guy like me!
Ok, let me play around a little with this, and we'll see what comes out of it!
btw, is Justification=1 to center the text?! ... and, where exactly do I write these scripts? In ued I guess, but I cant find that script editor! :noob:

Yes, Justification=1 is to center it. 0 is left and 2 is right alignment, respectively.

You can write these scripts with whatever you like. I personally use ConTEXT. In this package, for example:

1. The package name is MohlraaxGUI, so I created a folder in my UT2004 folder called MohlraaxGUI.
2. I created a folder named Classes in the MohlraaxGUI folder.
3. I created a file named MohlraaxServerLoading.uc in the Classes folder.
4. I put all the stuff I had before into that file.
5. I created a copy of GUI2K4.int called MohlraaxGUI.int and edited it a bit.
6. I edited my UT2004.ini, added MohlraaxGUI to EditPackages (so it could be compiled) and changed my ConnectingMenuClass.
7. I opened a command window in UT2004/System and typed ucc make.

Originally posted by Format Life:
This is a bit OT, but is it possible to change the messages on the screen (in example; "Head Shot!") without affecting AntiTCC and stuff?

Head shot specifically, I have no idea. Look in the .int files. I know you can change the spree messages, for example:

OMG hax! :noob: This is slightly ruined by the fact that the computer still screams 'Wicked Sick!' at me, but oh well

Edit: Head shot:

XGame.int
[SpecialKillMessage]
DecapitationString="Head Shot!!"

Back up your edited .int files after you're done, since patches overwrite them. The great thing is, .int file editing doesn't cause problem with online play, since you can't cheat by editing your .int files.

[musilowski]

OK, thanks for teh info! :up:

[legacy-breadbaker]

been out running after work and now I come back here and ...

the stuff I been looking for since customizing loading screens.
two thumbs for you, neoflame :up: :up: . You got a new fan.

[legacy-neoflame]

Maybe I'll write a utility for the simpler folk to create their own loadscreens

But I have to test online/ATCC compatibility first...

Edit: It appears to work online; I just conencted to Flak's server (which was playing... eww.... Serpentine :down: ) successfully.

[legacy-Mohlraax]

OMG it works!

I even compiled it myself!

Ok, along the way, some questions came up:

The folders and stuff we/you made... was it only for organizing the files? I can have my uncompiled scripts wherever I want?
... and when I compiled the file, it made MohlraaxGUI.u out of it... can I now delete MohlraaxServerLoading.uc from the system folder?!
... and last... when I compare GUI2K4.int and MohlraaxGUI.int... they look veeery different... what excatly did you do? What info was neede? And the GUI2K4.int is still in use... right?!

... now theres just a little more stuff that needs to be done, and you will see why I neede this... its not big thing tho..

[legacy-neoflame]

1. The folder structure is actually very important. If MohlraaxServerLoading was in MohlraaxGUI/Files, it wouldn't have been compiled. If it was in MohlraaxStuff/Classes, the output package would have been MohlraaxStuff.u. Etc.
2. MohlraaxServerLoading is in your MohlraaxGUI/Classes folder, not your System folder, right? :weird: In any case if you're not going to recompile MohlraaxGUI you can go ahead and delete it, but there's no particular reason to do so.
3. GUI2K4 comes with UT2004, and does a bazillion things, including UT2K4ServerLoading. MohlraaxGUI is custom, and only does one thing, a custom server loading screen. However, GUI2K4 is still being used for everything else that it does (that MohlraaxGUI doesn't.) MohlraaxGUI.int is actually the same thing as GUI2K4.int, but with all the stuff I don't need removed (because MohlraaxGUI doesn't do it) and some stuff modified (such as changing UT2K4ServerLoading to MohlraaxServerLoading.)

[legacy-Mohlraax]

AHA! That clearefies alot!

Dunno 'bout you guys... but I learned a shtload along the way! Thansk again neoflame! :up:

[legacy-neoflame]

No problem.

[legacy-Meroin]

A little off topic: Is there a way to change the NON vehicle death messages? I changed those in the Onslaught.ini.

Also, I know it's possible, so how do i get it so say 'You Pwned -person you killed-' for example?

[legacy-neoflame]

1. XWeapons.int
2.

XGame.int
[xKillerMessagePlus]
YouKilled="You killed"

(later)

[xVictimMessage]
YouWereKilledBy="You were killed by"
KilledByTrailer="!"

[legacy-3pyon]

ok then, i have a question.

Reguarding game sounds.
I wanted to use the original sounds for killing spree, return flag, and capture flag 1 and 2 in ut2004.

I exported them from Ued2, imported them into Ued3, in the game sounds > ut2oo3 fanfare.

but when i loaded game, i couldnt connect to a server because of incompatible file. any help? :S

[legacy-neoflame]

I'm not entirely sure what you mean...

You want to use the UT2003 announcer for certain things and the UT2004 one for others? Or what?

There's a built-in UT2K3 announcer in UT2K4 if that's what you're looking for. :weird: