UDKPawn's Postrenderer Isnt Working

[westclif]

Pls, Epic fix the native PostRendererFor function in the UDK Pawn, for the next release...


More Information about this Problem in this topic:
UDKPawn's Postrenderer Isnt Working (http://forums.epicgames.com/showthread.php?t=808767)

[Solid Snake]

Works for me just fine. Log is outputted with information from the function call.

DebugHUD.uc


class DebugHUD extends HUD;

function PostRender()
{
local DebugPawn DebugPawn;
local Vector CameraLocation;
local Rotator CameraRotation;

Super.PostRender();

ForEach DynamicActors(class'DebugPawn', DebugPawn)
{
AddPostRenderedActor(DebugPawn);
}

if (PlayerOwner != None)
{
PlayerOwner.GetPlayerViewpoint(CameraLocation, CameraRotation);
DrawActorOverlays(CameraLocation, CameraRotation);
}
}

defaultproperties
{
}


DebugGameInfo


class DebugGameInfo extends SimpleGame;

defaultproperties
{
HUDType=class'DebugHUD'
}


DebugPawn


class DebugPawn extends UDKPawn
placeable;

var DynamicLightEnvironmentComponent LightEnvironment;

simulated function PostBeginPlay()
{
Super.PostBeginPlay();
PlayerReplicationInfo = Spawn(class'PlayerReplicationInfo');
}

simulated function PostRenderFor(PlayerController PC, Canvas Canvas, vector CameraPosition, vector CameraDir)
{
`Log("PostRenderFor("$PC$","$Canvas$","$CameraPosition$","$CameraDir$")");
Super.PostRenderFor(PC, Canvas, CameraPosition, CameraDir);
}

defaultproperties
{
Begin Object Class=DynamicLightEnvironmentComponent Name=MyLightEnvironment
bSynthesizeSHLight=TRUE
bIsCharacterLightEnvironment=TRUE
bUseBooleanEnvironmentShadowing=FALSE
End Object
Components.Add(MyLightEnvironment)
LightEnvironment=MyLightEnvironment

Begin Object Class=SkeletalMeshComponent Name=WPawnSkeletalMeshComponent
bCacheAnimSequenceNodes=FALSE
AlwaysLoadOnClient=true
AlwaysLoadOnServer=true
bOwnerNoSee=true
CastShadow=true
BlockRigidBody=TRUE
bUpdateSkelWhenNotRendered=false
bIgnoreControllersWhenNotRendered=TRUE
bUpdateKinematicBonesFromAnimation=true
bCastDynamicShadow=true
Translation=(Z=8.0)
RBChannel=RBCC_Untitled3
RBCollideWithChannels=(Untitled3=true)
LightEnvironment=MyLightEnvironment
bOverrideAttachmentOwnerVisibility=true
bAcceptsDynamicDecals=FALSE
AnimTreeTemplate=AnimTree'CH_AnimHuman_Tree.AT_CH_ Human'
bHasPhysicsAssetInstance=true
TickGroup=TG_PreAsyncWork
MinDistFactorForKinematicUpdate=0.2
bChartDistanceFactor=true
RBDominanceGroup=20
Scale=1.075
bUseOnePassLightingOnTranslucency=TRUE
bPerBoneMotionBlur=true
End Object
Mesh=WPawnSkeletalMeshComponent
Components.Add(WPawnSkeletalMeshComponent)

TeamBeaconMaxDist=16384.f
bPostRenderOtherTeam=true
bPostRenderIfNotVisible=true
}

[westclif]

mhm funny isnt working for me either way...

tried to redo everything like you did but it wont work...

//EDIT: Ok found it, but why is the One from the UdkPawn just working with, a PlayerReplicationInfo ???